Il est possible d'ajouter un briefing directement via un module dans la mission via EDEN… c'est très fortement recommandé. Il est impossible en passant par là de mettre la moindre mise en forme.

La méthode classique est de créer un fichier (idéalement) à la racine de votre mission ( %UserProfile%\Documents\Arma 3\mpmissions\**VOTRE_MISSION** )

====== Initialiser le briefing ======

Il y a 2 actions à faire :

  - Créer un fichier **briefing.sqf**
  - Créer ou modifier le fichier **initPlayerLocal.sqf**

Vous devez avoir cette ligne dans le fichier **initPlayerLocal.sqf**, de préférence dans les premières lignes.

<code>
execVM "briefing.sqf"; // script qui ajoute le briefing
</code>

Pour l'explication, **initPlayerLocal.sqf** n'est exécuté que chez les joueurs et pas sur le serveur… Le serveur n'a pas vraiment besoin d'avoir le briefing ;)

====== Comment écrire son briefing ? ======

Le cas classique s'écrit avec cette ligne :

<code>
player createDiaryRecord ["Diary", ["TITRE", "
    DESCRIPTION DU BRIEFING
"]];
</code>

Comment ça fonctionne ?

<code>
player
</code>

Va impacter le joueur courant, soit le joueur chez qui on exécute le code, et il sera exécuté chez tout le monde, chacun de son côté.

<code>
createDiaryRecord 
</code>

Est la méthode qui nous permet d'ajouter une note au briefing sur la map, avec l'option “Diary” pour donner le type qu'on veut ajouter

Le titre et la description, c'est à vous de les écrire.

<note tip>Remarque : le premier que vous notez sera le dernier de la liste. Inversement, le dernier écrit sera le premier en jeu !</note>

====== Exemple de modèle de briefing par Shinriel ======

<code>
player createDiaryRecord ["Diary", ["Credits", "
    Mission faite par Shinriel, 
    <br/>en espérant qu'elle plaise.
"]];

player createDiaryRecord ["Diary", ["Matériel", "
  <font color='#FA5858'>Radios :</font>
  <br/>148 sur squad leader, teams leaders,
  <br/>343 pour tout le monde
  <br/>Voir le roaster pour plus d'informations.

  <br/><br/><font color='#FA5858'>Equipement :</font>

  <br/><br/><font color='#FA5858'>Véhicules :</font>    
"]];

player createDiaryRecord ["Diary", ["Renseignements", "
    <br/><br/><font color='#5858FA'>Intel :</font>

    <br/><br/><font color='#5858FA'>Forces ennemies :</font>

    <br/><br/><font color='#5858FA'>Présence de civil :</font>
"]];

player createDiaryRecord ["Diary", ["Mission", "
    <br/><br/>description courte

    <br/><br/><font color='#5858FA'>Objectifs :</font>

    <br/><br/><font color='#5858FA'>ELement spécifique à la mission :</font>

    <br/><br/>Accomplissement des objectifs à l'appréciation du chef d'opération.
    <br/>Coupure de la mission avec la commande radio 0-0-9 (victoire) ou 0-0-1 (défaite).
"]];
</code>

<code>
player createDiaryRecord ["Diary", ["Context", "
  Context de la mission, surtout pas la mission à faire, mais ce qu'y se passe avant la mission par exemple.
"]];
</code>

====== Couleur, image, ... ======

De base, le retour à la ligne n'existe pas tel quel dans le briefing, c'est à vous de dire quand vous voulez un retour à la ligne

<code>
<br/>
</code>

Permet de le faire.

Donc

<code>
<br/><br/>
</code>

Permet de faire une ligne vide (on revient 2 fois à la ligne)

Dans le même genre on peut ajouter de la couleur

<code>
<font color='#5858FA'>Texte en couleur</font>
</code>

Qui ajoute la couleur #5858FA. Vous pouvez sélectionner la couleur que vous voulez [[https://htmlcolorcodes.com/fr/|sur ce site]]

Pour afficher une image

<code>
<img image='images\monter.jpg' width='360' height='280' />
</code>

Ici on vient chercher une image qui se trouve dans le dossier de la mission, puis dans le dossier **images**, l'image **monter.jpg**.

width et height sont les tailles en pixels de l'image qu'on veut afficher. Si vous voulez redimensionner votre image, attention à garder ses dimensions proportionnelles. Merci la règle de trois

Une image de 720x560px, si on veut avoir une largeur max de 360px, =⇒ 360 * 560 / 720 (largeur souhaitée * hauteur d'origine / largeur d'origine) =⇒ 280px

<note important>Évitez de donner à **width** une valeur supérieure à 360, elle sortirait de la fenêtre de briefing.</note>

<code>
<marker name='mkr_mon_marqueur'>Mon marqueur cliquable !</marker>
</code>

On permet de cliquer sur ce texte, pour envoyer la map en direction du marqueur du nom **mkr_mon_marqueur**

<note warning>Attention à ne pas mettre un marqueur HORS de la carte, le fait de cliquer sur le texte concerné, peut prendre énormément de temps et bloquer l'interface des personnes ayant fait l'erreur de cliquer dessus !</note>

Pour une [[https://community.bistudio.com/wiki/createDiaryRecord|version complète des tags utilisables]]

====== Avancé, script et personnalisation ======

Il est possible de n'afficher un briefing que pour une ou quelques personnes. Le plus simple est d'ajouter un nom de variable sur une unité ou sur un groupe afin de l'utiliser

<code>
player createDiaryRecord ["Diary", ["Tout le monde", "
    blabla
"]];

if(group player == vipTeam) then {
    player createDiaryRecord ["Diary", ["Pour le groupe du vip", "
        blabla
    "]];
};

if(player == vip) then {
    player createDiaryRecord ["Diary", ["Pour le VIP seulement", "
        blabla
    "]];
} else {
    player createDiaryRecord ["Diary", ["Tout le monde sauf le VIP", "
        blabla                
    "]];
};

if(side player == blufor) then {
    player createDiaryRecord ["Diary", ["Seulement pour les blufor", "
        blabla
    "]];
};
</code>

Mais il est aussi possible de personnaliser le message en particulier

Avec des conditions et plusieurs textes possibles

<code>
player createDiaryRecord ["Diary", ["Mission", "
    <br/><br/><font color='#5858FA'>Désamorçage :</font>
    " + 
    (if (params_expert_demo == 0) then {
        "<br/>Tout vos hommes ont été formé pour désamorcer les bombes."
    } else {
        "<br/>Seul les expert en explosifs savent rentrer les codes de désamorçage sur les bombes."
    })
    + "
    <br />123
"]];
</code>

Mais on peut aussi afficher du texte

<code>
player createDiaryRecord ["Diary", ["Renseignement", "
  <br />Notre chef " + (name playerLeader) + " connait son métier
"]];
</code>